WhyCan Forum(哇酷开发者社区)

flex-A

会员

注册时间： 2019-08-27

已发帖子： 51

积分： 151.5

全志H616裸机求助

各位大佬好，小弟最近想在全志H616（quad cortex-A53）上构建裸机程序，参考uboot和经大佬指点后，实现如下：
1、H616上电后包括BROM运行在arm32模式，需要手动切换到aarch64位模式运行。
2、切换方式是32位模式下写RMR寄存器触发warm reset，warm reset后切换到64位模式，并且跳转到RVBAR寄存器所指的地址运行。
3、32位模式下提前设置RVBAR，然后写RMR触发warm reset。这些指令提前编译成字节码嵌入到64位程序中。

*切换运行模式的代码如下（抠自uboot）：
这个代码在32位模式下会触发warn reset，在64位模式下会跳转到reset标志。
0x00020060是代码加上BROM头在SRAM里地址，即第一条指令的地址。

#define CONFIG_SUN50I_GEN_H6

/*
 * Switch into AArch64 if needed.
 * Refer to arch/arm/mach-sunxi/rmr_switch.S for the original source.
 */
	tst     x0, x0                  // this is "b #0x84" in ARM (a litle trick here)
	b       reset
	.space  0x7c

	.word	0xe28f0058	// add     r0, pc, #88
	.word	0xe59f1054	// ldr     r1, [pc, #84]
	.word	0xe0800001	// add     r0, r0, r1
	.word	0xe580d000	// str     sp, [r0]
	.word	0xe580e004	// str     lr, [r0, #4]
	.word	0xe10fe000	// mrs     lr, CPSR
	.word	0xe580e008	// str     lr, [r0, #8]
	.word	0xee11ef10	// mrc     15, 0, lr, cr1, cr0, {0}
	.word	0xe580e00c	// str     lr, [r0, #12]
	.word	0xee1cef10	// mrc     15, 0, lr, cr12, cr0, {0}
	.word	0xe580e010	// str     lr, [r0, #16]

	.word	0xe59f1024	// ldr     r1, [pc, #36] ; 0x170000a0
	.word	0xe59f0024	// ldr     r0, [pc, #36] ; CONFIG_*_TEXT_BASE
	.word	0xe5810000	// str     r0, [r1]
	.word	0xf57ff04f	// dsb     sy
	.word	0xf57ff06f	// isb     sy
	.word	0xee1c0f50	// mrc     15, 0, r0, cr12, cr0, {2} ; RMR
	.word	0xe3800003	// orr     r0, r0, #3
	.word	0xee0c0f50	// mcr     15, 0, r0, cr12, cr0, {2} ; RMR
	.word	0xf57ff06f	// isb     sy
	.word	0xe320f003	// wfi
	.word	0xeafffffd	// b       @wfi
#ifndef CONFIG_SUN50I_GEN_H6
	.word	0x017000a0	// writeable RVBAR mapping address
#else
	.word	0x09010040	// writeable RVBAR mapping address
#endif
.word	0x00020060 //30:	.word	0xffffffff jump to this address when switch to aarch64 sucessfully
#endif

*点灯代码如下（已验证）：

.global _start
_start:
//led
reset:
	ldr x0,=0x0300B04c
	ldr x1,=0x77177777
	str x1,[x0]
	ldr x0,=0x0300b058
	ldr x1,=0x00002000
	str x1,[x0]
1:
	b 1b
	.space  0x7c

很简单的代码，现在的问题是它下进去led点不亮。我这边没啥头绪，还请坛里大佬指点指点:D

riturbo

会员

注册时间： 2022-06-22

已发帖子： 2

积分： 27

Re: 全志H616裸机求助

首先可以把保存状态的那段汇编删掉，就是space后面到空行。然后可以考虑两点.  1.最终的0x20060就不太合适，光是这个头里的.space就不止0x60, 可以考虑把这个头在后面补全到0x100这么长，就是在.word 0x20060后面继续.space,看起来清爽点,。如果你的代码是挨着这个头的那就可以把20060换成0x20100.  2. sram有没有被rom之类的代码使用？ 可以尝试直接用ddr地址。  最后最好代码贴完整点……

liuyuedong

会员

注册时间： 2020-02-09

已发帖子： 38

积分： 28

Re: 全志H616裸机求助

有两种改法：
1.加上全志的判断的头部（可参考f1c200s的裸机），这种改法烧到 sram 和 spi flash 中都可以运行
2.将0x20060改成0x20000,烧到sram中可运行

操作32位的地址寄存器使用w0 - w30 别用 x0 - x30

flex-A

会员

注册时间： 2019-08-27

已发帖子： 51

积分： 151.5

Re: 全志H616裸机求助

感谢@riturbo，@liuyuedong两位大佬出手相助，这段时间手头H616一直在吃灰，没及时回复。
问题解决了，h616是64位内核，外设寄存器是32位的，操作32位的地址寄存器使用w0 - w30 而不是 x0 - x30。
如下是正确的点灯代码

.global _start
_start:
//led
reset:
	ldr x0,=0x0300B04c
	ldr w1,=0x77177777
	str w1,[x0]
	ldr x0,=0x0300b058
	ldr w1,=0x00002000
	str w1,[x0]
1:
	b 1b
	.space  0x7c

最近编辑记录 flex-A (2023-02-18 16:58:50)

是我

会员

注册时间： 2023-03-20

已发帖子： 1

积分： 31

Re: 全志H616裸机求助

各位大佬好，我最近也在研究H616这款Soc,我是刚开始学习汇编的，想在板子上用汇编跑LED裸机程序，尝试了很多遍led都没反应。大佬帮忙看一下，谢谢

这是LED点灯的代码：myStart.S

.global _start

_start :
    b reset
reset :
    bl gpio_init
    bl led_on

loop :
    b loop

gpio_init :
    ldr x15,=0x0300B04C
    ldr w16,=0x77177777
    str w16,[x15]

    ldr x15,=0x0300B064     //pull up
    ldr w16,=0x01000000
    str w16,[x15]
    ret
led_on :  
    ldr x15,=0x0300B058    //set 1
    ldr w16,=0x00002000
    str w16,[x15]
    ret

链接脚本 mystart.lds

OUTPUT_FORMAT("elf64-littleaarch64", "elf64-littleaarch64", "elf64-littleaarch64")
OUTPUT_ARCH(aarch64)
ENTRY(_start)
SECTIONS
{
    . = 0x00020060;
    . = ALIGN(8);
    .text :
    {
        myStart.o(.text*)
        *(.text*)
    }
    . = ALIGN(8);
    .data : {
        *(.data*)
    }
    . = ALIGN(8);
    .bss : 
    {
        *(.bss*)
    }
}

Makefile

AS = aarch64-linux-gnu-as
CC = aarch64-linux-gnu-gcc
LD = aarch64-linux-gnu-ld
OBJCOPY = aarch64-linux-gnu-objcopy

all : myStart.o
	$(LD) -Tmystart.lds -o myStart.elf $^
	$(OBJCOPY) -O binary myStart.elf myStart.bin
	./mksunxiboot myStart.bin myStart_sunxi.bin

%.o : %.S
	$(CC) -g -c $^

%.o : %.c
	$(CC) -g -c $^

clean :
	@rm -rf *.bin *.o *.elf
	@echo clean OK

flex-A

会员

注册时间： 2019-08-27

已发帖子： 51

积分： 151.5

Re: 全志H616裸机求助

@是我
H616上电后默认是32位模式，需要切换到64位模式去执行你的点灯代码。

Plywenlong

会员

注册时间： 2024-05-21

已发帖子： 2

积分： 2

Re: 全志H616裸机求助

求助。。。为什么我把程序放sd卡。发现只能运行32位程序，不能切换到64位